// Script: Aliens vs Predator
// Author: Natalya[AF]
// Version: Beta 0.2A

block config
{
	// Time before the join message is displayed.
	es_xsetinfo p_delay 14
	es_xsetinfo p_max server_var(zombie_timer_min)
}


block load
{
	es_doblock avpredator/config
	es_doblock avpredator/setup
	es_regsaycmd alienmelol avpredator/alien "ITS THE ONLY WAY TO BE SURE"
	es_msg #green  = Alien vs Predator is IN EFFECT =
	es_msg #green One player will spawn as a Predator
	es_msg #green and will have 10 seconds to run.  Kill
	es_msg #green the Predator to get to be the Predator
	es_msg #green during the next round.
}


block unload
{
	es_msg #green Alien vs Predator is no longer in effect.
	es_msg #green Normal play will now resume.
	es_unregsaycmd alienmelol
}


// Script Introduction
event player_activate
{
	es_delayed server_var(p_delay) es_tell event_var(userid) #green = Alien vs Predator is IN EFFECT =
	es_delayed server_var(p_delay) es_tell event_var(userid) #green One player will spawn as a Predator
	es_delayed server_var(p_delay) es_tell event_var(userid) #green and will have 10 seconds to run.  Kill
	es_delayed server_var(p_delay) es_tell event_var(userid) #green the Predator to get to be the Predator
	es_delayed server_var(p_delay) es_tell event_var(userid) #green during the next round.
}


// Version Info
event player_say
{
	if (event_var(text) equalto !predatorinfo) do
	{
		es_tell event_var(userid) #green |=== Alien vs Predator ===|
		es_tell event_var(userid) #green Script by Natalya[AF]
		es_tell event_var(userid) #green www.N00bUnlimited.net
		es_tell event_var(userid) #green Version: Beta 0.2A
	}
}


block setup
{
	zombie_respawn_as_zombie 1
	es_set predator "0" "Predator ID"
	zombie_timer_min  4
	zombie_timer_max  14
}


event player_spawn
{
	es_setinfo temp_id event_var(userid)
	if (server_var(temp_id) != server_var(predator)) do
	{
		if (server_var(aliens) == 1) do
		{
			es_setinfo spwn_plyr "0"
			es_format spwn_plyr "#%1" event_var(userid)
			es sm_exec server_var(spwn_plyr) "say alienmelol"
		}
	}
}


event player_team
{
	if (event_var(team) == 1) do
	{
		es_setinfo spec event_var(userid)
		if (server_var(spec) == server_var(predator)) then es_setinfo predator "0"
		if (server_var(spec) == server_var(pred_killer)) then es_setinfo pred_killer "0"
	}
}

event player_disconnect
{
	es_setinfo disc event_var(userid)
	if (server_var(disc) == server_var(predator)) then es_setinfo predator "0"
	if (server_var(disc) == server_var(pred_killer)) then es_setinfo pred_killer "0"
}

event es_map_start
{
	zombie_respawn_as_zombie 1
	zombie_timer_min  4
	zombie_timer_max  14
}

event round_start
{
	if (server_var(predator) == 0) do
	{
		es_delayed 1.0 getrandplayer predator #alive
		es_delayed 1.1 es_xsetinfo aliens 0
		es_delayed 1.2 es_msg #green [AvP] Round Start!!  Predator will spawn after the first Zombie makes a kill.
	}
}

event zombification
{
	if (event_var(attacker) == -1) do
	{
		if (server_var(aliens) == 0) do
		{
			es_setinfo 1st_zombie event_var(userid)
			if (server_var(1st_zombie) != server_var(predator)) do
			{
				es_setinfo aliens 1
				es_doblock avpredator/start_pred
			}
			if (server_var(1st_zombie) == server_var(predator)) do
			{
				getrandplayer predator #alive
				es_setinfo aliens 1
				es_doblock avpredator/start_pred
			}
		}
	}
}

block start_pred
{
	es_setinfo sm_pred_id "0"
	es_format sm_pred_id "#%1" server_var(predator)
	es_msg #green [AvP] The Predator Has Spawned!!
	es_msg #green [AvP] Kill the Predator to be Predator Next Round!!
	es_tell server_var(predator) #green [AvP] You are the Predator Motherfucka!!
	es_setplayerprop server_var(predator) "CCSPlayer.m_iAccount" 0
	es_setplayerprop server_var(predator) "CCSPlayer.baseclass.m_iHealth" 255
	es_setplayerprop server_var(predator) "CBasePlayer.localdata.m_flLaggedMovementValue" 1.1
	es sm_disarm server_var(sm_pred_id)
	es_give server_var(predator) weapon_knife
	es_give server_var(predator) weapon_m3
	es_give server_var(predator) weapon_deagle
	es_give server_var(predator) item_nvgs
	es sm_forcemodel server_var(sm_pred_id) models/player/slow/predator_xp/predator_xp.mdl
	es_keysetvalue expl_players server_var(predator) expl "1"
	es sm_freeze @all
	es sm_god @all 1
	es sm_freeze server_var(sm_pred_id) 0.1
	es sm_god server_var(sm_pred_id) 0
	es sm_exec @t "say alienmelol"
	es_delayed 1 es sm_exec @ct "say alienmelol"
	es_delayed 2 es sm_exec @ct "say alienmelol"
	es_delayed 10 es sm_unfreeze @all
	es_delayed 10 es sm_god @all 0
}

event player_death
{
	if (server_var(aliens) == 1) do
	{
		if (event_var(userid) == server_var(predator)) do
		{
			es_keysetvalue expl_players server_var(predator) expl "0"
			es_setinfo pred_killer event_var(attacker)
			es_msg #green [AvP] event_var(es_attackername) killed the Predator!!
			es_msg #green [AvP] event_var(es_attackername) is the new Predator!!
			es_setinfo aliens "0"
			es_delayed 2.58 es_forcevalue sv_cheats 1
			es_delayed 2.59 es endround
			es_delayed 2.60 es_forcevalue sv_cheats 0
		}
	}
}

event round_end
{
	es_keysetvalue expl_players server_var(predator) expl "0"
	if (server_var(pred_killer) != 0) do
	{
		es_setinfo predator server_var(pred_killer)
		es_setinfo pred_killer "0"
	}
	es_setinfo aliens "0"
}

block alien
{
	es_set plyr "0"
	es_getcmduserid plyr
        if (server_var(plyr) != server_var(predator)) do
        {
                es_setinfo plyr_id "0"
                es_format plyr_id "#%1" server_var(plyr)
                es zombie_player server_var(plyr_id)
                es sm_forcemodel server_var(plyr_id) models/player/slow/aliendrone_v3/slow_alien.mdl
        }
}