// Buy level
// ---------
//
// Originally made by Cagemonkey.
// Edited by psycho_wizrd.
//
//----------
//
// psycho_wizrd's Contributions:
//
// Death penalty
// Suicide Penalty
// Teamkill Penalty
// Level Difference System
// Multikill System
// Mugmod Conversion
// Betting System


block config
{

	es_xset betting_enabled 1		// betting enabled?
	es_xset betting_announce 1		// Advertise being used?
	es_xset betting_start_timer 0		// In seconds, how long do they have to bet. 0 = Entire Round
	es_xset betting_min_bet 0		// Minimum bet
	es_xset betting_max_bet 500		// Maximum bet. 0 = None
	es_xset betting_ratios 1		// Use ratios for winning bets? (prevents last second bets for lots of money)

	es_xset mugger_enabled 1		// MugMod // 1 = ON // 0 = OFF //
	es_xset mugger_percentage 60		// Percentage to steal from Victim? //
	es_xset mugger_announce 1		// Advertise Mugger? // 1 = YES // 0 = NO //

	es_xset buy_kill_reward 20
	es_xset buy_death_penalty 10
	es_xset buy_suicide_penalty 50
	es_xset buy_tk_penalty 100
	
	es_xset buy_level_reward 10
	es_xset buy_level_cost 600

	// How many levels below can a victim be? 0=off
	es_xset buy_level_dif 2

	// Can one gain extra money by killing multiple without dieing? (Spreads across rounds)
	es_xset buy_multikill_reward 100	// 0 = off
	es_xset buy_multikill_kills 4		// Kills required to get bonus
	es_xset buy_multikill_show_msgs 1	// Show Streaks

	// List of weapons that cannot be bypassed
	// List weapons separated by commas, NO SPACES!
	es_xset buy_no_skip "hegrenade,knife"
	
	// Enable announcement to players that this script is loaded
	// 0=off, 1=on
	es_xset buy_announce 1
}

block load
{
	// Init vars

	// Betting Initial vars
	es_xset betting_bets_taken 0
	es_xset betting_amount 0
	es_xset betting_player_amount 0
	es_xset betting_ratio 0
	es_xset betting_ratiot 0
	es_xset betting_ratioct 0
	es_xset betting_team 0
	es_xset betting_player_team 0
	es_xset betting_ct_alive 0
	es_xset betting_t_alive 0
	es_xset betting_userid 0
	es_xset betting_winner 0
	es_xset betting_winnings 0
	es_xset betting_check_team 0
	es_xset bet_query 0
	es_xset betting_no_bet 0
	es_xset betting_temp_winnings 0

	es_xset death_userid 0
	es_xset buy_query 0
	es_xset buy_userid 0
	es_xset buy_money 0
	es_xset buy_multikill 0
	es_xset buy_weapon 0
	es_xset buy_flag 0
	es_xset buy_level 0
	es_xset buy_menu 0
	es_xset buy_temp 0
	es_xset buy_attacker_level 0
	es_xset buy_victim_level 0
	
	// Init db
	es_xsql open buy_db ":memory:"
	es_xsql query buy_db "DROP TABLE IF EXISTS buy_players"
	//buy_db buy_players fields: userid, money
	es_xsql query buy_db "CREATE TABLE IF NOT EXISTS buy_players(userid int, money int DEFAULT 0, multikill int DEFAULT 0, bet_team int DEFAULT 0, bet_amount int DEFAULT 0, bet_ratio float DEFAULT 0.0, flag int(1) DEFAULT 0)"
	
	// Register say command
	es_xregsaycmd !buylevel "gungame4/addons/custom/gg_buy_level/buy_cmd" "Allows players to buy a level"
	es_xregsaycmd !bet "gungame4/addons/custom/gg_buy_level/place_bet" "Allows players to place a bet"
	
	// Load config
	es_xdoblock gungame4/addons/custom/gg_buy_level/config
	
	// Add current players
	foreach player buy_userid #all "es_xdoblock gungame4/addons/custom/gg_buy_level/player_setup"
}

event round_start
{
	ifx true(buy_announce) do
	{
		es_msg #multi #green[#lightgreenBuyLevel#green] #default is ON, type !buylevel
	}
	ifx true(betting_announce) do
	{
		ifx true(betting_enabled) do
		{
			es_xset betting_bets_taken 0
			es_msg #multi #green[#lightgreenBetting#green] #default is#green Enabled#default, type !bet <#greenCT#default/#greenT#default> <#greenAmount#default/#greenALL#default>
			ifx true(betting_start_timer) do
			{
				es_msg #multi #green[#lightgreenBetting#green] #defaultYou have#green server_var(betting_start_timer) #defaultto place your bets.
				es_delayed server_var(betting_start_timer) es_msg #multi #green[#lightgreenBetting#green] #defaultBetting windows are CLOSED.
				es_delayed server_var(betting_start_timer) es_xset betting_bets_taken 1
			}
		}
	}
	ifx true(mugger_announce) do
	{
		ifx true(mugger_enabled) do
		{
			es_msg #multi #green[MugMod]#default Mugging is in effect. Take a player's money by killing them with a knife.
		}
	}
}

event round_end
{
	ifx true(betting_enabled) do
	{
		foreach player betting_userid #all "es_xdoblock gungame4/addons/custom/gg_buy_level/check_bets"
		es_set betting_winner event_var(winner)
	}
}

block check_bets
{
	es_xformatqv bet_query "SELECT bet_amount FROM buy_players WHERE userid = '%1'" betting_userid
	es_sql queryvalue buy_db betting_amount server_var(bet_query)

	es_xformatqv bet_query "SELECT bet_team FROM buy_players WHERE userid = '%1'" betting_userid
	es_sql queryvalue buy_db betting_team server_var(bet_query)

	es_xformatqv bet_query "SELECT bet_ratio FROM buy_players WHERE userid = '%1'" betting_userid
	es_sql queryvalue buy_db betting_ratio server_var(bet_query)

	if ( server_var(betting_winner) == server_var(betting_team) ) do
	{
		es_set betting_winnings server_var(betting_amount)

		ifx true(betting_ratios) do
		{
			es_math betting_winnings float
			es_math betting_winnings * server_var(betting_ratio)
			es_math betting_winnings int
		}

		es_xformatqv bet_query "SELECT money FROM buy_players WHERE userid = '%1'" betting_userid
		es_sql queryvalue buy_db betting_player_amount server_var(bet_query)

		es_math betting_player_amount + server_var(betting_winnings)

		es_xformatqv bet_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" betting_player_amount betting_userid
		es_sql query buy_db server_var(bet_query)

		es playerset cash server_var(betting_userid) server_var(betting_player_amount)
	}
	else do
	{
		es_xformatqv bet_query "SELECT money FROM buy_players WHERE userid = '%1'" betting_userid
		es_sql queryvalue buy_db betting_player_amount server_var(bet_query)

		es_math betting_player_amount - server_var(betting_amount)

		es_xformatqv bet_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" betting_player_amount betting_userid
		es_sql query buy_db server_var(bet_query)

		es playerset cash server_var(betting_userid) server_var(betting_player_amount)
	}
}
		

block place_bet
{
	es_xgetcmduserid betting_userid
	ifx true(betting_enabled) do
	{
		if (server_var(betting_bets_taken) == 0 ) do
		{
			es_getargv betting_team 1
			es_getargv betting_amount 2

			if ( server_var(betting_team) == "CT" ) do
			{
				es_xset betting_check_team 1
				es_xset betting_team 2
			}
			if ( server_var(betting_team) == "T" ) do
			{
				es_xset betting_check_team 1
				es_xset betting_team 3
			}
			ifx false(betting_check_team) do
			{
				es_tell server_var(betting_userid) #multi #green[#lightgreenBetting#green] #defaultTeam was not recognized.
				es_xset betting_no_bet 1
			}

			es_xformatqv bet_query "SELECT money FROM buy_players WHERE userid = '%1'" betting_userid
			es_sql queryvalue buy_db betting_player_amount server_var(bet_query)

			if ( server_var(betting_amount) == "ALL" ) do
			{
				es_set betting_amount server_var(betting_player_amount)
			}
			if ( server_var(betting_amount) > server_var(betting_player_amount) ) do
			{
				es_tell server_var(betting_userid) #multi #green[#lightgreenBetting#green] #defaultYour bet was higher than what you have.
				es_xset betting_no_bet 1
			}
			if ( server_var(betting_amount) > server_var(betting_max_bet) ) do
			{
				es_tell server_var(betting_userid) #multi #green[#lightgreenBetting#green] #defaultYour bet was higher than the maximum bid.#green server_var(betting_max_bet)
				es_xset betting_no_bet 1
			}
			if ( server_var(betting_amount) < server_var(betting_min_bet) ) do
			{
				es_tell server_var(betting_userid) #multi #green[#lightgreenBetting#green] #defaultYour bet was lower than the minimum bid.#green server_var(betting_min_bet)
				es_xset betting_no_bet 1
			}
			if ( server_var(betting_amount) < 0 ) do
			{
				es_tell server_var(betting_userid) #multi #green[#lightgreenBetting#green] #defaultYou cannot bet less than 0.
				es_xset betting_no_bet 1
			}

			ifx false(betting_no_bet) do
			{
				es_xformatqv bet_query "UPDATE buy_players SET bet_team = '%1' WHERE userid = '%2'" betting_team betting_userid
				es_sql query buy_db server_var(bet_query)

				es_xformatqv bet_query "UPDATE buy_players SET bet_amount = '%1' WHERE userid = '%2'" betting_amount betting_userid
				es_sql query buy_db server_var(bet_query)
				
				es_xset betting_ratio 0
				es_xset betting_temp_winnings 0
				es_math betting_temp_winnings float

				es_math betting_temp_winnings + server_var(betting_amount)

				ifx true(betting_ratios) do
				{
					es_xset betting_ct_alive 0
					es_xset betting_t_alive 0
					foreach player buy_userid #CT#Alive "es_math betting_ct_alive + 1"
					foreach player buy_userid #T#Alive "es_math betting_t_alive + 1"

					es_xset betting_ratiot 0
					es_math betting_ratiot float
					es_math betting_ratiot + server_var(betting_ct_alive)
					es_math betting_ratiot / server_var(betting_t_alive)

					es_xset betting_ratioct 0
					es_math betting_ratioct float
					es_math betting_ratioct + server_var(betting_t_alive)
					es_math betting_ratioct / server_var(betting_ct_alive)

					if (server_var(betting_team) == 2) then es_set betting_ratio server_var(betting_ratiot)
					if (server_var(betting_team) == 3) then es_set betting_ratio server_var(betting_ratioct)
					es_math betting_temp_winnings * server_var(betting_ratio)
				}

				es_math betting_temp_winnings int

				es_xformatqv bet_query "UPDATE buy_players SET bet_ratio = '%1' WHERE userid = '%2'" betting_ratio betting_userid
				es_sql query buy_db server_var(bet_query)

				if (server_var(betting_team) == 2) then es_msg #multi #green[#lightgreenBetting#green] #defaultA bet for#green server_var(betting_amount) #default has been placed on #greenT#default. ( Rewards:#green server_var(betting_temp_winnings) #default)
				if (server_var(betting_team) == 3) then es_msg #multi #green[#lightgreenBetting#green] #defaultA bet for#green server_var(betting_amount) #default has been placed on #greenCT#default. ( Rewards:#green server_var(betting_temp_winnings) #default)
			}
		}
	}
}

event es_map_start
{
	// Since we do not need to keep any info when the map changes, we delete the database each map_start
	es_xsql query buy_db "DROP TABLE IF EXISTS buy_players"
	es_xsql query buy_db "CREATE TABLE IF NOT EXISTS buy_players(userid int, money int DEFAULT 0, multikill int DEFAULT 0, bet_team int DEFAULT 0, bet_amount int DEFAULT 0, bet_ratio float DEFAULT 0.0, flag int(1) DEFAULT 0)"
}

event player_activate
{
	// Add players to the database when they join the server
	es_set buy_userid event_var(userid)
	es_xformatqv buy_query "INSERT INTO buy_players ('userid', 'money', 'multikill', 'bet_team', 'bet_amount', 'bet_ratio') VALUES ('%1', '0', '0', '0', '0', '0')" buy_userid
	es_sql query buy_db server_var(buy_query)
}

block player_setup
{
	// Add players to the database that may already be connected to the server
	es_xformatqv buy_query "INSERT INTO buy_players ('userid', 'money', 'multikill', 'bet_team', 'bet_amount', 'bet_ratio') VALUES ('%1', '0', '0', '0', '0', '0')" buy_userid
	es_sql query buy_db server_var(buy_query)
}

event player_spawn
{
	// Make sure the player is actually in the game first
	if (event_var(es_userteam) > 1) do
	{
		// Check how much money the database says they should have and set their current cash level
		es_set buy_userid event_var(userid)
		es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
		es_sql queryvalue buy_db buy_money server_var(buy_query)
		es playerset cash server_var(buy_userid) server_var(buy_money)
	}
}

event player_death
{
	if (event_var(attacker) > 0) do
	{
		es gg_getlevel buy_attacker_level event_var(attacker)
	}
	es gg_getlevel buy_victim_level event_var(userid)
	es_math buy_victim_level + server_var(buy_level_dif)
	es_set buy_userid event_var(attacker)
	es_set death_userid event_var(userid)

	//-------------------------------------------   Mugmod Section   -------------------------------------------

	if (server_var(mugger_enabled) > 0) do
	{
		if (event_var(weapon) == knife) do
		{
			ifx true(buy_level_dif) do
			{
				if (server_var(buy_attacker_level) <= server_var(buy_victim_level)) do
				{
					es_xset mugger_killercash 0
					es_xset mugger_victimcash 0

					es_xformatqv buy_query "SELECT money FROm buy_players WHERE userid = '%1'" death_userid
					es_sql queryvalue buy_db mugger_victimcash server_var(buy_query)

					es_xformatqv buy_query "SELECT money FROm buy_players WHERE userid = '%1'" buy_userid
					es_sql queryvalue buy_db mugger_killercash server_var(buy_query)

					es_setinfo mugger_prize server_var(mugger_victimcash)
					es_math mugger_prize * server_var(mugger_percentage)
					es_math mugger_prize / 100

					es_math mugger_victimcash - server_var(mugger_prize)
					es_math mugger_killercash + server_var(mugger_prize)
					if ( server_var(mugger_killercash) > 16000 ) then es_xset mugger_killercash 16000

					es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" mugger_victimcash death_userid
					es_sql query buy_db server_var(buy_query)
					es playerset cash server_var(death_userid) server_var(buy_money)

					es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" mugger_killercash buy_userid
					es_sql query buy_db server_var(buy_query)
					es playerset cash server_var(buy_userid) server_var(buy_money)
				}
			}
			else do
			{
				es_xset mugger_killercash 0
				es_xset mugger_victimcash 0

				es_xformatqv buy_query "SELECT money FROm buy_players WHERE userid = '%1'" death_userid
				es_sql queryvalue buy_db mugger_victimcash server_var(buy_query)

				es_xformatqv buy_query "SELECT money FROm buy_players WHERE userid = '%1'" buy_userid
				es_sql queryvalue buy_db mugger_killercash server_var(buy_query)

				es_setinfo mugger_prize server_var(mugger_victimcash)
				es_math mugger_prize * server_var(mugger_percentage)
				es_math mugger_prize / 100

				es_math mugger_victimcash - server_var(mugger_prize)
				es_math mugger_killercash + server_var(mugger_prize)
				if ( server_var(mugger_killercash) > 16000 ) then es_xset mugger_killercash 16000

				es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" mugger_victimcash death_userid
				es_sql query buy_db server_var(buy_query)
				es playerset cash server_var(death_userid) server_var(buy_money)

				es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" mugger_killercash buy_userid
				es_sql query buy_db server_var(buy_query)
				es playerset cash server_var(buy_userid) server_var(buy_money)
			}
		}
	}

	//------------------------------------------- End of Mugmod Section ----------------------------------------


	ifx false(gg_warmup_started) do
	{
		// If the player died because of world or suicide, we do not need to continue further
		if (event_var(attacker) > 0) do
		{
			if (event_var(attacker) == event_var(userid)) do
			{
				ifx true(buy_suicide_penalty) do
				{
					es_xformatqv buy_query "SELECT money FROm buy_players WHERE userid = '%1'" death_userid
					es_sql queryvalue buy_db buy_money server_var(buy_query)
					es_math buy_money - server_var(buy_suicide_penalty)
					if (server_var(buy_money) < 0) then es_xset buy_money 0
					es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money death_userid
					es_sql query buy_db server_var(buy_query)
					es playerset cash server_var(death_userid) server_var(buy_money)
				}
			}
			else do
			{

				if (event_var(es_userteam) == event_var(es_attackerteam)) do
				{
					ifx true(buy_tk_penalty) do
					{
						es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
						es_sql queryvalue buy_db buy_money server_var(buy_query)
						es_math buy_money - server_var(buy_tk_penalty)
						if (server_var(buy_money) < 0) then es_xset buy_money 0
						es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
						es_sql query buy_db server_var(buy_query)
						es playerset cash server_var(buy_userid) server_var(buy_money)
					}
				}
				else do
				{
					ifx true(buy_kill_reward) do
					{
						ifx true(buy_level_dif) do
						{
							if (server_var(buy_attacker_level) <= server_var(buy_victim_level)) do
							{
								// Add 1 to multikill value
								es_xformatqv buy_query "SELECT multikill FROM buy_players WHERE userid = '%1'" buy_userid
								es_sql queryvalue buy_db buy_multikill server_var(buy_query)
								es_math buy_multikill + 1
								es_xformatqv buy_query "UPDATE buy_players SET multikill = '%1' WHERE userid = '%2'" buy_multikill buy_userid
								es_sql query buy_db server_var(buy_query)

								// Reward Kill within Level Range
								es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
								es_sql queryvalue buy_db buy_money server_var(buy_query)
								es_math buy_money + server_var(buy_kill_reward)
								if (server_var(buy_money) > 16000) then es_xset buy_money 16000
								es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
								es_sql query buy_db server_var(buy_query)
								es playerset cash server_var(buy_userid) server_var(buy_money)
							}
							else do
							{
								es_tell event_var(attacker) #multi #green[#lightgreenBuyLevel#green] #defaultYou may not gain money or increase streak from a player out of your level range.
							}
						}
					}
					else do
					{
						// Add 1 to multikill value
						es_xformatqv buy_query "SELECT multikill FROM buy_players WHERE userid = '%1'" buy_userid
						es_sql queryvalue buy_db buy_multikill server_var(buy_query)
						es_math buy_multikill + 1
						es_xformatqv buy_query "UPDATE buy_players SET multikill = '%1' WHERE userid = '%2'" buy_multikill buy_userid
						es_sql query buy_db server_var(buy_query)

						// Reward Kill
						es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
						es_sql queryvalue buy_db buy_money server_var(buy_query)
						es_math buy_money + server_var(buy_kill_reward)
						if (server_var(buy_money) > 16000) then es_xset buy_money 16000
						es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
						es_sql query buy_db server_var(buy_query)
						es playerset cash server_var(buy_userid) server_var(buy_money)
					}
					ifx true(buy_death_penalty) do
					{
						es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" death_userid
						es_sql queryvalue buy_db buy_money server_var(buy_query)
						es_math buy_money - server_var(buy_death_penalty)
						if (server_var(buy_money) > 16000) then es_xset buy_money 16000
						es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money death_userid
						es_sql query buy_db server_var(buy_query)
						es playerset cash server_var(death_userid) server_var(buy_money)
					}
				}
			}
		}
	}
	// Player was killed, reset multikill
	es_xformatqv buy_query "UPDATE buy_players SET multikill = '0' WHERE userid = '%1'" death_userid
	es_sql queryvalue buy_db buy_multikill server_var(buy_query)
	es_tell server_var(death_userid) Streak Failed.

	// Update Money from database in all cases
	es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
	es_sql queryvalue buy_db buy_money server_var(buy_query)
	es playerset cash server_var(buy_userid) server_var(buy_money)
	ifx true(buy_multikill_reward) do
	{
		es_xformatqv buy_query "SELECT multikill FROM buy_players WHERE userid = '%1'" buy_userid
		es_sql queryvalue buy_db buy_multikill server_var(buy_query)
		if (server_var(buy_multikill) != server_var(buy_multikill_kills)) do
		{
			if (server_var(buy_multikill_show_msgs) == 1) then es_tell event_var(attacker) #multi #green[#lightgreenBuyLevel#green] #defaultCurrent Streak:#green server_var(buy_multikill) #default/#green server_var(buy_multikill_kills)
		}

		if (server_var(buy_multikill) == server_var(buy_multikill_kills)) do
		{
			es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
			es_sql queryvalue buy_db buy_money server_var(buy_query)
			es_math buy_money + server_var(buy_multikill_reward)
			if (server_var(buy_money) > 16000) then es_xset buy_money 16000
			es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
			es_sql query buy_db server_var(buy_query)
			es playerset cash server_var(buy_userid) server_var(buy_money)

			es_xformatqv buy_query "UPDATE buy_players SET multikill = '0' WHERE userid = '%1'" buy_userid
			es_sql query buy_db server_var(buy_query)
			if (server_var(buy_multikill_show_msgs) == 1) then es_tell event_var(attacker) #multi #green[#lightgreenBuyLevel#green] server_var(buy_multikill_reward) #defaulthas been added to your bank for completing your streak of#green server_var(buy_multikill_kills)
		}
	}
}

event gg_levelup
{
	// If players do not receive a reward for leveling up, stop here
	ifx true(buy_level_reward) do
	{
		es_set buy_userid event_var(userid)
		// If player is leveling up because they bought a level, do not give cash for this level
		es_xformatqv buy_query "SELECT flag FROM buy_players WHERE userid = '%1'" buy_userid
		es_sql queryvalue buy_db buy_flag server_var(buy_query)
		ifx false(buy_flag) do
		{
			// Give reward for leveling up, and update their cash and the database
			es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
			es_sql queryvalue buy_db buy_money server_var(buy_query)
			es_math buy_money + server_var(buy_level_reward)
			if (server_var(buy_money) > 16000) then es_xset buy_money 16000
			es playerset cash server_var(buy_userid) server_var(buy_money)
			es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
			es_sql query buy_db server_var(buy_query)
		}
		else do
		{
			es_xformatqv buy_query "UPDATE buy_players SET flag = '0' WHERE userid = '%1'" buy_userid
			es_sql query buy_db server_var(buy_query)
			es_tell server_var(buy_userid) #multi #green[#lightgreenBuyLevel#green] #default You have purchased level#lightgreen event_var(new_level)
		}
	}
}

block buy_cmd
{
	es_xgetcmduserid buy_userid
	// Check to see if this weapon can be skipped by buying the next level
	es gg_getweapon buy_weapon server_var(buy_userid)
	if (server_var(buy_weapon) notin server_var(buy_no_skip)) do
	{
		// Check to make sure they are not on the last level
		es gg_getlevel buy_level server_var(buy_userid)
		gg_getmaxlevel buy_temp
		if (server_var(buy_level) != server_var(buy_temp)) do
		{
			// Get their money and if they have enough, give them a level
			es_xformatqv buy_query "SELECT money FROM buy_players WHERE userid = '%1'" buy_userid
			es_sql queryvalue buy_db buy_money server_var(buy_query)
			es_math buy_money - server_var(buy_level_cost)
			if (server_var(buy_money) >= 0) do
			{
				// Player has enough money, level them up and update their cash and the database
				es_xformatqv buy_query "UPDATE buy_players SET money = '%1' WHERE userid = '%2'" buy_money buy_userid
				es_sql query buy_db server_var(buy_query)
				// Set flag to prevent players from gaining cash from buying levels
				es_xformatqv buy_query "UPDATE buy_players SET flag = '1' WHERE userid = '%1'" buy_userid
				es_sql query buy_db server_var(buy_query)
				es playerset cash server_var(buy_userid) server_var(buy_money)
				es gg_levelup server_var(buy_userid)
				// Check to see if turbo mode is on, and if not, give weapon now
				es_xset gg_exists 0
				es_xexists gg_exists script gungame4/addons/gg_turbo_mode
				ifx false(gg_exists) do
				{
					es_getplayerprop gg_tmp server_var(buy_userid) "CCSPlayer.baseclass.pl.deadflag"
					ifx false(gg_tmp) do
					{
						es_give server_var(buy_userid) player_weaponstrip
						es_fire server_var(buy_userid) player_weaponstrip Strip 1
						es_delayed 0.01 es_xgive server_var(buy_userid) item_assaultsuit
						es_delayed 0.01 es_xgive server_var(buy_userid) weapon_knife
						es_delayed 0.01 gg_equip server_var(buy_userid) event_var(team)
					}
				}
			}
			else do
			{
				// Player does not have enough money
				es_tell server_var(buy_userid) #multi #green[#lightgreenBuyLevel#green] #default You do not have enough money.
				es_xformatv buy_menu " [BuyLevel]: %1\n------------\n Kill Reward: %2\n Death Penalty: %3\n Suicide Penalty: %4\n TeamKill Penalty: %5\n Level Reward: %6\n Multikill Reward: %7\n Multikill Kills: %8\n \n Lowbie Protection: ON\n Level Difference: %9\n \n------------\n->  0: Exit" buy_level_cost buy_kill_reward buy_death_penalty buy_suicide_penalty buy_tk_penalty buy_level_reward buy_multikill_reward buy_multikill_kills buy_level_dif
				es_menu 5 server_var(buy_userid) server_var(buy_menu)
			}
		}
		else do
		{
			// Player is on the last level and cannot skip
			es_tell server_var(buy_userid) #multi #green[#lightgreenBuyLevel#green] #default You cannot skip level server_var(buy_level) by buying it!
		}
	}
	else do
	{
		// Player cannot skip this level
		es_tell server_var(buy_userid) #multi #green[#lightgreenBuyLevel#green] #default You cannot skip server_var(buy_weapon) by buying it!
	}
}

block unload
{
	// Remove the database from memory and delete the say command we created
	es_xsql close buy_db
	es_xunregsaycmd !buylevel
	es_xunregsaycmd !bet
	
	// Remove announcement
	crontab del buylevel
}